home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Ahoy 1985 August
/
Ahoy_Magazine_85-08_1985_Double_L.d64
/
helicopter blade
(
.txt
)
< prev
next >
Wrap
Commodore BASIC
|
2022-10-26
|
929b
|
27 lines
0 print"[147]":poke53280,4:poke53281,1:poke646,11
1 rem sound effects
2 rem helicopter blades
3 rem humming sound in voice 0 suggests you are in helicopter
4 rem to hear more distant chopper, remove ":poke gt(0),17" from line 40
10 gosub 900:goto 100
20 for i=1 to 2:poke ad(i),48:poke sr(i),16:next:poke fh(1),20:poke fh(2),40
25 poke ad(0),34:poke sr(0),49:poke fh(0),10
30 poke vl,15:print "press shift to stop sound"
40 poke gt(1),129:poke gt(2),129:poke gt(0),17
50 for i=10 to 220 step 70:poke fh(1),i:poke fh(2),i:next
60 poke gt(1),0:poke gt(2),0:poke gt(0),0:if peek(653)=0 then 40
70 if peek(653)<>0 then 70
90 return
99 rem routine to play sounds when shift is pressed
100 print "press shift to hear sound"
110 if peek(653)=0 then 110
120 gosub 20:goto 100
898 rem routine to set up variables
899 rem set up sound control addresses
900 fl(0)=54272:fh(0)=54273:gt(0)=54276:ad(0)=54277:sr(0)=54278
905 for i=1 to 2:x=i*7:fl(i)=fl(0)+x:fh(i)=fh(0)+x:gt(i)=gt(0)+x:ad(i)=ad(0)+x
906 sr(i)=sr(0)+x:next
909 rem set volume address
910 vl=54296
990 return